HardwareAdapter/master/master.ino

#include <Wire.h>
#include <ArduinoMqttClient.h>
#include <Ethernet.h>

#include "config.h"
#include "global.h"

#define READ_BYTES_FROM_WIRE 1

#define HEADING_SIM_UP "sim/autopilot/heading_up"
#define HEADING_SIM_DOWN "sim/autopilot/heading_down"
#define ALTITUDE_SIM_UP "sim/autopilot/altitude_up"
#define ALTITUDE_SIM_DOWN "sim/autopilot/altitude_down"
#define AIRSPEED_SIM_UP "sim/autopilot/airspeed_up"
#define AIRSPEED_SIM_DOWN "sim/autopilot/airspeed_down"

#define MQTT_SIM_COMMAND_TOPIC "/xplane/meta/cmnd"
#define MQTT_SIM_DEVICE_TOPIC "/xplane/meta/device"
#define MQTT_SIM_LOG_TOPIC "/xplane/meta/log"
#define MQTT_SIM_VALUE_TOPIC "/xplane/rref/#"

#define MQTT_KEEPALIVE_INTERVAL_MS 15000

struct device {
  byte address;       // I2C address of device
  char *name;        // name of this device
  char name1[3];      // first name to send on init of device
  char *highCommand1; // command to use if TRIGGER_BIT_1 is set and HIGH_BIT_1 is set
  char *lowCommand1;  // command to use if TRIGGER_BIT_1 is set and HIGH_BIT_1 is not set
  char name2[3];      // second name to send on init of device
  char *highCommand2; // command to use if TRIGGER_BIT_2 is set and HIGH_BIT_2 is set
  char *lowCommand2;  // command to use if TRIGGER_BIT_2 is set and HIGH_BIT_2 is not set
};

struct device devices[] = {
  { 0x08, "Heading Speed", {'H', 'D', 'G'}, HEADING_SIM_UP, HEADING_SIM_DOWN, {'S', 'P', 'D'}, AIRSPEED_SIM_UP, AIRSPEED_SIM_DOWN }
};

int numDevices = -1;

byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };

const char broker[] = "openhab.sugarland.lan";
int        port     = 1883;
const char topic[]  = MQTT_SIM_VALUE_TOPIC;

EthernetClient client;
char localIP[16];
MqttClient mqttClient(client);
unsigned long mqttLastKeepAlive = millis();

void onMqttMessage(int messageSize) {
//  // we received a message, print out the topic and contents
//  Serial.println("Received a message with topic '");
//  Serial.print(mqttClient.messageTopic());
//  Serial.print("', length ");
//  Serial.print(messageSize);
//  Serial.println(" bytes:");
//
//  // use the Stream interface to print the contents
//  while (mqttClient.available()) {
//    Serial.print((char)mqttClient.read());
//  }
//  Serial.println();
//
//  Serial.println();
}

void sendMqttMessage(char *topic, int n, ...) {
  mqttClient.beginMessage(topic);
  va_list args;
  va_start(args, n);
  for (int i = 0; i < n; i++) {
    mqttClient.print(va_arg(args, char*));
  }
  va_end(args);
  mqttClient.endMessage();
}

void sendI2CInit(struct device d) {
  sendMqttMessage(MQTT_SIM_LOG_TOPIC, 2, "Sending init to ", d.name);
  Wire.beginTransmission(d.address);
  Wire.write(DATA_RESET_BYTE);
  Wire.write(DATA_INIT_BYTE_1);
  Wire.write(d.name1, 3);
  Wire.write(DATA_INIT_BYTE_2);
  Wire.write(d.name2, 3);
  Wire.endTransmission(d.address);
}

void setup() {
  // count devices for loop
  numDevices = sizeof(devices) / sizeof(device);

  // start the Ethernet connection:
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
    while (1);
  }
  // print your local IP address:
  sprintf(localIP, "%d.%d.%d.%d", Ethernet.localIP()[0], Ethernet.localIP()[1], Ethernet.localIP()[2], Ethernet.localIP()[3]);
  Serial.println(localIP);

  // MQTT auth
  mqttClient.setUsernamePassword(MQTT_USER, MQTT_PASS);

  // MQTT connection
  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1);
  } else {
    Serial.println("MQTT connected");
    sendMqttMessage(MQTT_SIM_DEVICE_TOPIC, 1, "Master online");
  }

  // subscribe to MQTT topic
  mqttClient.onMessage(onMqttMessage);
  mqttClient.subscribe(topic);
  mqttClient.setKeepAliveInterval(10 * 1000L);

  // start I2C
  Wire.begin();

  // for debugging
  pinMode(LED_TX, OUTPUT);
  digitalWrite(LED_TX, HIGH);
  pinMode(LED_RX, OUTPUT);
  digitalWrite(LED_RX, HIGH);

  // initialize devices
  for (int i = 0; i < numDevices; i++) {
    sendI2CInit(devices[i]);
  }
}

void loop() {
  // loop through devices and ask for data
  for (int i = 0; i < numDevices; i++) {
    Wire.requestFrom(devices[i].address, READ_BYTES_FROM_WIRE);
    while (Wire.available()) {
      // device has data, ask as long for data as it sends
      // if it never stops sending, we are fucked :)
      byte data = Wire.read();
      if (data == DATA_STOP_BYTE) {
        // do not request further data
        continue;
      } else if (data == DATA_RESET_BYTE) {
        // device needs initialization
        sendMqttMessage(MQTT_SIM_LOG_TOPIC, 2, "got reset byte from ", devices[i].name);
        sendI2CInit(devices[i]);
      } else {
        // handle as payload
        if (data & TRIGGER_BIT_1) {
          if (data & HIGH_BIT_1) {
            sendMqttMessage(MQTT_SIM_COMMAND_TOPIC, 1, devices[i].highCommand1);
          } else {
            sendMqttMessage(MQTT_SIM_COMMAND_TOPIC, 1, devices[i].lowCommand1);
          }
        } else if (data & TRIGGER_BIT_2) {
          if (data & HIGH_BIT_2) {
            sendMqttMessage(MQTT_SIM_COMMAND_TOPIC, 1, devices[i].highCommand2);
          } else {
            sendMqttMessage(MQTT_SIM_COMMAND_TOPIC, 1, devices[i].lowCommand2);
          }
        } else {
          // who are you?
        }
      }

      Wire.requestFrom(devices[i].address, READ_BYTES_FROM_WIRE);
    }
  }

  // transmit MQTT keepalive message if MQTT_KEEPALIVE_INTERVAL_MS is reached
  // or millis() is wrapping to 0
  if (mqttLastKeepAlive + MQTT_KEEPALIVE_INTERVAL_MS < millis() || mqttLastKeepAlive > millis()) {
    sendMqttMessage(MQTT_SIM_DEVICE_TOPIC, 1, localIP);
    mqttLastKeepAlive = millis();
  }
}